li7y/flake.nix

# SPDX-FileCopyrightText: 2024 Simon Bruder <simon@sbruder.de>
#
# SPDX-License-Identifier: AGPL-3.0-or-later

{
  inputs = {
    flake-utils.url = "github:numtide/flake-utils";

    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";

    rust-overlay.url = "github:oxalica/rust-overlay";

    naersk.url = "github:nix-community/naersk";

    git-hooks.url = "github:cachix/git-hooks.nix";
  };

  outputs = { self, flake-utils, nixpkgs, rust-overlay, naersk, git-hooks }: flake-utils.lib.eachDefaultSystem (system:
    let
      pkgs = import nixpkgs {
        inherit system;
        overlays = [ rust-overlay.overlays.default ];
      };

      rustPackage = pkgs.rust-bin.stable.latest.default;
      rustPackageNightly = pkgs.rust-bin.nightly.latest.default;
      rustPackageDev = rustPackageNightly;

      naersk' = pkgs.callPackage naersk {
        rustc = rustPackage;
        cargo = rustPackage;
      };
    in
    {
      checks = {
        pre-commit-check = git-hooks.lib.${system}.run {
          src = self;
          hooks = {
            cargo-check = {
              enable = true;
              package = rustPackageDev;
            };
            cargo-deny = {
              enable = true;
              name = "cargo-deny";
              entry = "cargo deny check";
              pass_filenames = false;
            };
            clippy = {
              enable = true;
              settings = {
                denyWarnings = true;
              };
              packageOverrides = {
                cargo = rustPackageDev;
                clippy = rustPackageDev;
              };
            };
            nixpkgs-fmt.enable = true;
            reuse = {
              enable = true;
              name = "reuse";
              entry = "reuse lint";
              pass_filenames = false;
            };
            rustfmt = {
              enable = true;
              packageOverrides = {
                cargo = rustPackageDev;
                rustfmt = rustPackageDev;
              };
            };
          };
        };
      };

      packages =
        let
          # naersk does not easily allow overrideAttrs
          commonNaerskConfigurarion = {
            src = self;

            checkInputs = with pkgs; [
              postgresql
              postgresqlTestHook
            ];

            # otherwise the deps derivation is also tested (which just wastes time as there are no tests)
            overrideMain = (o: o // {
              doCheck = true;
            });

            # tests need to be able to create and drop databases
            postgresqlTestUserOptions = "LOGIN SUPERUSER";

            postgresqlTestSetupPost = ''
              export DATABASE_URL="postgres://''${PGUSER}/''${PGDATABASE}?port=5432&host=''${PGHOST}"
            '';

            # Otherwise SQLx tries to infer the databse schema from an empty database
            # (as it can only run the migrations once the test binary is built).
            # Also, this enforces that the full query cache is included in the repository.
            SQLX_OFFLINE = true;
          };
        in
        rec {
          li7y = naersk'.buildPackage commonNaerskConfigurarion;
          default = li7y;

          li7y-tarpaulin = naersk'.buildPackage (commonNaerskConfigurarion // {
            name = "li7y-tarpaulin";

            checkInputs = commonNaerskConfigurarion.checkInputs ++ (with pkgs; [
              cargo-tarpaulin
            ]);

            dontBuild = true;
            singleStep = true; # tarpaulin uses different options anyway

            cargoTestCommands = _: [ "cargo tarpaulin" ];

            postInstall = ''
              rm -r $out
              cp -r target/tarpaulin $out
            '';
          });

          li7y-oci = pkgs.dockerTools.buildLayeredImage {
            name = "li7y";
            tag = "latest";

            contents = [
              li7y
            ];

            config = {
              Cmd = [ "${li7y}/bin/li7y" ];
            };
          };
        };

      devShells.default = pkgs.mkShell {
        buildInputs = [
          rustPackageDev
        ] ++ (with pkgs; [
          cargo-deny
          cargo-tarpaulin
          cargo-watch
          graphviz
          postgresql
          reuse
          sqlx-cli
        ]);

        shellHook = ''
          ${self.checks.${system}.pre-commit-check.shellHook}
        '';
      };
    });
}