nixos-config/users/simon/default.nix

{ config, pkgs, ... }:
{
  imports = [
    (import "${(import ../../nix/sources.nix).home-manager}/nixos")
  ];

  users.users.simon = {
    isNormalUser = true;
    extraGroups = [
      "adbusers"
      "dialout"
      "docker"
      "libvirtd"
      "lp"
      "networkmanager"
      "video"
      "wheel"
    ];
    openssh.authorizedKeys.keys = config.sbruder.pubkeys.trustedKeys;
    initialPassword = "foobar"; # for vm
  };

  home-manager.useUserPackages = true;
  home-manager.useGlobalPkgs = true;

  home-manager.users.simon = { lib, pkgs, ... }: {
    # FIXME: those options are duplicates from the system configuration
    options.sbruder = {
      gui.enable = lib.mkOption {
        type = lib.types.bool;
        default = config.sbruder.gui.enable;
        description = "Whether to enable gui";
      };
      unfree = {
        allowAssets = lib.mkOption {
          default = config.sbruder.unfree.allowAssets;
          type = lib.types.bool;
          description = "Allow restricted selection of unfree assets to be installed.";
        };
        allowSoftware = lib.mkOption {
          default = config.sbruder.unfree.allowSoftware;
          type = lib.types.bool;
          description = "Allow restricted selection of unfree software to be installed.";
        };
      };
    };

    imports = [ ./modules ];
  };
}