nixos-config/pkgs/default.nix

self: super:
let
  inherit (super) callPackage;
  srcs = import ./srcs.nix;
in
{
  bang-evaluator = import srcs.bang-evaluator { pkgs = self; };

  bwrap-helper = callPackage ./bwrap-helper { };

  osu-lazer = callPackage ./osu-lazer { inherit (super) osu-lazer; };
  osu-lazer-sandbox = callPackage ./osu-lazer-sandbox { };

  wordclock-dimmer = super.python3Packages.callPackage ./wordclock-dimmer { };

  sbruder = super.recurseIntoAttrs {
    imprint = callPackage ./imprint { };
  };

  aria2_exporter = import srcs.aria2_exporter { pkgs = self; };

  # adapted nixpkgs upstream but changed to buildGoModule and updated to
  # version that works in my setup
  prometheus-fritzbox-exporter = callPackage ./prometheus-fritzbox-exporter { };

  # FIXME: 21.05: Move to home-manager module package attribute
  mpv-unwrapped = super.mpv-unwrapped.overrideAttrs (o: o // {
    patches = [
      # FIXME: 21.05: Remove since it has mpv 0.33
      (super.fetchpatch {
        url = "https://github.com/mpv-player/mpv/commit/43c13e5ea23230edca38426d4a9eed049a70890e.patch";
        sha256 = "0g73ws36cs2hfzqck6xiaimj5yd5hz68b4wf3qayyv4nrf5sz02c";
      })
    ];
  });

  mpvScripts = (super.mpvScripts or { }) // {
    pitchcontrol = callPackage ./mpv-scripts/pitchcontrol { };
  };

  # TODO: Remove patch once mako > 1.4.1 is released and in nixpkgs
  mako = super.mako.overrideAttrs (o: o // {
    patches = [
      # Adds makoctl set
      (super.fetchpatch {
        url = "https://github.com/emersion/mako/commit/782ef66b04d5d927fe19254be175e0b5ddff343f.patch";
        sha256 = "1qjaxhf11fyysmi9l8vwrz2vag3lcbllx8y8v2fgg3p52a7cwdjs";
      })
    ];
  });

  cyanrip = callPackage ./cyanrip { };

  # TODO: Remove when pavucontrol > 4.0 is released
  pavucontrol = super.pavucontrol.overrideAttrs (o: o // {
    patches = [
      # This fixes context menus on wayland
      # Bug report: https://gitlab.freedesktop.org/pulseaudio/pavucontrol/-/issues/63
      # Merge Request: https://gitlab.freedesktop.org/pulseaudio/pavucontrol/-/merge_requests/20
      (super.fetchpatch {
        url = "https://gitlab.freedesktop.org/pulseaudio/pavucontrol/-/commit/ae278b8643cf1089f66df18713c8154208d9a505.patch";
        sha256 = "066vhxjz6gmi2sp2n4pa1cdsxjnq6yml5js094g5n7ld34p84dpj";
      })
    ];
  });
}