nixos-config/machines/renge/services/sbruder.xyz/default.nix

{ pkgs, ... }:

{
  imports = [
    ./blocks.nix
  ];

  services.nginx.virtualHosts."sbruder.xyz" = {
    forceSSL = true;
    enableACME = true;

    root = pkgs.stdenvNoCC.mkDerivation {
      name = "sbruder.xyz";

      src = ./.;

      nativeBuildInputs = with pkgs; [ pandoc ];

      buildPhase = ''
        runHook preBuild

        pandoc \
            -s \
            --metadata-file metadata.yaml \
            -f commonmark_x \
            -t html5 \
            -o index.html \
            index.md

        runHook postBuild
      '';

      installPhase = ''
        runHook preInstall
        install -D index.html $out/index.html
        runHook postInstall
      '';
    };

    locations = {
      "/imprint/".alias = "${pkgs.sbruder.imprint}/";
      "/transparency/" = {
        alias = "${./transparency}/";
        extraConfig = ''
          autoindex on;
          charset utf-8;
        '';
      };
    };
  };
}