nixos-config/pkgs/default.nix

self: super:
let
  srcs = import ./srcs.nix;
in
{
  bang-evaluator = import srcs.bang-evaluator { pkgs = self; };

  bwrap-helper = super.callPackage ./bwrap-helper { };

  osu-lazer = super.callPackage ./osu-lazer { inherit (super) osu-lazer; };
  osu-lazer-sandbox = super.callPackage ./osu-lazer-sandbox { };

  wordclock-dimmer = super.python3Packages.callPackage ./wordclock-dimmer { };

  sbruder = super.recurseIntoAttrs {
    imprint = super.callPackage ./imprint { };
  };

  aria2_exporter = import srcs.aria2_exporter { pkgs = self; };

  # FIXME: 21.05: Move to home-manager module package attribute
  mpv-unwrapped = super.mpv-unwrapped.overrideAttrs (o: o // {
    patches = [
      # FIXME: 21.05: Remove since it has mpv 0.33
      (super.fetchpatch {
        url = "https://github.com/mpv-player/mpv/commit/43c13e5ea23230edca38426d4a9eed049a70890e.patch";
        sha256 = "0g73ws36cs2hfzqck6xiaimj5yd5hz68b4wf3qayyv4nrf5sz02c";
      })
    ];
  });

  # TODO: Remove patch once mako > 1.4.1 is released and in nixpkgs
  mako = super.mako.overrideAttrs (o: o // {
    patches = [
      # Adds makoctl set
      (super.fetchpatch {
        url = "https://github.com/emersion/mako/commit/782ef66b04d5d927fe19254be175e0b5ddff343f.patch";
        sha256 = "1qjaxhf11fyysmi9l8vwrz2vag3lcbllx8y8v2fgg3p52a7cwdjs";
      })
    ];
  });
}