nixos-config/pkgs/default.nix

final: prev:
let
  inherit (prev) callPackage;
in
{
  bwrap-helper = callPackage ./bwrap-helper { };

  osu-lazer = callPackage ./osu-lazer { inherit (prev) osu-lazer; };
  osu-lazer-sandbox = callPackage ./osu-lazer-sandbox { };

  wordclock-dimmer = prev.python3Packages.callPackage ./wordclock-dimmer { };

  sbruder = prev.recurseIntoAttrs {
    imprint = callPackage ./imprint { };
  };

  # adapted nixpkgs upstream but changed to buildGoModule and updated to
  # version that works in my setup
  prometheus-fritzbox-exporter = callPackage ./prometheus-fritzbox-exporter { };

  # FIXME: 21.05: Move to home-manager module package attribute
  mpv-unwrapped = prev.mpv-unwrapped.overrideAttrs (o: o // {
    patches = [
      # FIXME: 21.05: Remove since it has mpv 0.33
      (prev.fetchpatch {
        url = "https://github.com/mpv-player/mpv/commit/43c13e5ea23230edca38426d4a9eed049a70890e.patch";
        sha256 = "0g73ws36cs2hfzqck6xiaimj5yd5hz68b4wf3qayyv4nrf5sz02c";
      })
    ];
  });

  # TODO: Remove patch once mako > 1.4.1 is released and in nixpkgs
  mako = prev.mako.overrideAttrs (o: o // {
    patches = [
      # Adds makoctl set
      (prev.fetchpatch {
        url = "https://github.com/emersion/mako/commit/782ef66b04d5d927fe19254be175e0b5ddff343f.patch";
        sha256 = "1qjaxhf11fyysmi9l8vwrz2vag3lcbllx8y8v2fgg3p52a7cwdjs";
      })
    ];
  });

  # TODO: Remove when pavucontrol > 4.0 is released
  pavucontrol = prev.pavucontrol.overrideAttrs (o: o // {
    patches = [
      # This fixes context menus on wayland
      # Bug report: https://gitlab.freedesktop.org/pulseaudio/pavucontrol/-/issues/63
      # Merge Request: https://gitlab.freedesktop.org/pulseaudio/pavucontrol/-/merge_requests/20
      (prev.fetchpatch {
        url = "https://gitlab.freedesktop.org/pulseaudio/pavucontrol/-/commit/ae278b8643cf1089f66df18713c8154208d9a505.patch";
        sha256 = "066vhxjz6gmi2sp2n4pa1cdsxjnq6yml5js094g5n7ld34p84dpj";
      })
    ];
  });

  # adapted from https://github.com/NixOS/nixpkgs/pull/85790
  # TODO: Remove when memtest86+ ≥ 5.31b is in nixpkgs
  memtest86plus = prev.memtest86plus.overrideAttrs (o: o // rec {
    version = "5.31b";

    src = prev.fetchurl {
      url = "https://www.memtest.org/download/${version}/memtest86+-${version}.tar.gz";
      sha256 = "028zrch87ggajlb5xx1c2ab85ggl9qldpibf45735sy0haqzyiki";
    };

    NIX_CFLAGS_COMPILE = null;

    buildFlags = [ ];

    doCheck = prev.stdenv.isi686;
    checkTarget = "run_self_test";
  });
}