final: prev:
let
  inherit (prev) callPackage;
in
{
  bwrap-helper = callPackage ./bwrap-helper { };

  co2_exporter = callPackage ./co2_exporter { };

  osu-lazer = callPackage ./osu-lazer { inherit (prev) osu-lazer; };
  osu-lazer-sandbox = callPackage ./osu-lazer-sandbox { };

  wordclock-dimmer = prev.python3Packages.callPackage ./wordclock-dimmer { };

  sbruder = prev.recurseIntoAttrs {
    contact = callPackage ./contact-page { };
    imprint = callPackage ./imprint { };
  };

  libbluray = prev.libbluray.override {
    withAACS = true;
    withBDplus = true;
  };

  grml-zsh-config = prev.grml-zsh-config.overrideAttrs (o: o // {
    postPatch = (o.postPatch or "") + ''
      substituteInPlace etc/zsh/zshrc \
          --replace 'isgrmlcd && HISTSIZE=500  || HISTSIZE=5000' "" \
          --replace 'isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000' ""
    '';
  });

  # FIXME: remove once manghud > 0.6.8 is in nixpkgs/intel arc works
  mangohud = prev.mangohud.overrideAttrs (o: {
    version = "unstable-2023-02-05";

    src = prev.fetchFromGitHub {
      owner = "flightlessmango";
      repo = "MangoHud";
      rev = "319077808668c589523853313d028cf81837ce72";
      fetchSubmodules = true;
      sha256 = "sha256-FHm5CcLKpD6R2XmGvlQrIU/OlkX1TGEN/ld3vrms2Lk=";
    };

    mesonFlags = o.mesonFlags ++ [
      "-Dappend_libdir_mangohud=false" # new default incompatible with current packaging
      "-Dtests=disabled" # tests require new subproject
    ];
  });

  # FIXME: Remove once khal from unstable passes tests again.
  khal = prev.khal.overridePythonAttrs (o: { doCheck = false; });

  mumble = prev.mumble.overrideAttrs (o: rec {
    version = "1.5.517";

    src = prev.fetchFromGitHub {
      owner = "mumble-voip";
      repo = "mumble";
      rev = "v${version}";
      sha256 = "sha256-NkpX1whtXDX3Q3UPnEO/Fq2LUX2MaJ/NI0oF7HudP+I=";
      fetchSubmodules = true;
    };

    patches = [ ];
  });

  vimPlugins = prev.vimPlugins // {
    # TODO: Remove once (if?) https://github.com/LnL7/vim-nix/pull/28 lands
    vim-nix = prev.vimPlugins.vim-nix.overrideAttrs (o: {
      patches = o.patches or [ ] ++ (map prev.fetchpatch [
        {
          url = "https://github.com/LnL7/vim-nix/commit/d298418ba10e1460b3b22106633731c2a9c1c83b.patch";
          sha256 = "sha256-JcSkHScZtEN7qLYKxQB3pasl98MBXVBilB1noLxJxb8=";
        }
        {
          url = "https://github.com/LnL7/vim-nix/commit/7b26edee3e2f63cce096aff65cfdaf995ebd92b0.patch";
          sha256 = "sha256-sId/HOUfYf5U9S3HgSmOsldRiEbXc5mVFol7M7CMdi8=";
        }
        {
          url = "https://github.com/LnL7/vim-nix/commit/7cad7f3666a63ff00f7ecd73a98886031901b918.patch";
          sha256 = "sha256-rSRPkCo1wLvyufQkOo3gOwHetxvLdI6L89r7UgApz54=";
        }
        {
          url = "https://github.com/LnL7/vim-nix/commit/6affa2b211b02a907ab3bc7064821be57ae93446.patch";
          sha256 = "sha256-/fFx2/v2bGLAf5xQD+Y5p79NyRQu2dRFNoc9sYXoglM=";
        }
      ]);
    });
  };
}