final: prev:
let
  inherit (prev) callPackage;
in
{
  bwrap-helper = callPackage ./bwrap-helper { };

  osu-lazer = callPackage ./osu-lazer { inherit (prev) osu-lazer; };
  osu-lazer-sandbox = callPackage ./osu-lazer-sandbox { };

  wordclock-dimmer = prev.python3Packages.callPackage ./wordclock-dimmer { };

  sbruder = prev.recurseIntoAttrs {
    contact = callPackage ./contact-page { };
    imprint = callPackage ./imprint { };
  };

  libbluray = prev.libbluray.override {
    withAACS = true;
    withBDplus = true;
  };

  # TODO: Remove when swaynotificationcenter ≥ 0.5 is in nixpkgs
  swaynotificationcenter = prev.swaynotificationcenter.overrideAttrs (o: o // rec {
    version = "0.5";

    src = prev.fetchFromGitHub {
      owner = "ErikReider";
      repo = "SwayNotificationCenter";
      rev = "v${version}";
      sha256 = "sha256-Jjbr6GJ0MHlO+T/simPNYQnB5b7Cr85j4GRjRGa5B6s=";
    };

    nativeBuildInputs = o.nativeBuildInputs ++ [ prev.scdoc ];
  });

  # adapted from https://github.com/NixOS/nixpkgs/pull/85790
  # TODO: Remove when memtest86+ ≥ 5.31b is in nixpkgs
  memtest86plus = prev.memtest86plus.overrideAttrs (o: o // rec {
    version = "5.31b";

    src = prev.fetchurl {
      url = "https://www.memtest.org/download/${version}/memtest86+-${version}.tar.gz";
      sha256 = "028zrch87ggajlb5xx1c2ab85ggl9qldpibf45735sy0haqzyiki";
    };

    NIX_CFLAGS_COMPILE = null;

    buildFlags = [ ];

    doCheck = prev.stdenv.isi686;
    checkTarget = "run_self_test";
  });

  vimPlugins = prev.vimPlugins // {
    # TODO: Remove once (if?) https://github.com/LnL7/vim-nix/pull/28 lands
    vim-nix = prev.vimPlugins.vim-nix.overrideAttrs (o: {
      patches = o.patches or [ ] ++ (map prev.fetchpatch [
        {
          url = "https://github.com/LnL7/vim-nix/commit/d298418ba10e1460b3b22106633731c2a9c1c83b.patch";
          sha256 = "sha256-JcSkHScZtEN7qLYKxQB3pasl98MBXVBilB1noLxJxb8=";
        }
        {
          url = "https://github.com/LnL7/vim-nix/commit/7b26edee3e2f63cce096aff65cfdaf995ebd92b0.patch";
          sha256 = "sha256-sId/HOUfYf5U9S3HgSmOsldRiEbXc5mVFol7M7CMdi8=";
        }
        {
          url = "https://github.com/LnL7/vim-nix/commit/7cad7f3666a63ff00f7ecd73a98886031901b918.patch";
          sha256 = "sha256-rSRPkCo1wLvyufQkOo3gOwHetxvLdI6L89r7UgApz54=";
        }
        {
          url = "https://github.com/LnL7/vim-nix/commit/6affa2b211b02a907ab3bc7064821be57ae93446.patch";
          sha256 = "sha256-/fFx2/v2bGLAf5xQD+Y5p79NyRQu2dRFNoc9sYXoglM=";
        }
      ]);
    });
  };
}