{ config, lib, pkgs, ... }:

{
  options = {
    accounts.email.accounts = lib.mkOption {
      type = lib.types.attrsOf (lib.types.submodule {
        options.aerc-sbruder.enable = lib.mkEnableOption "aerc (custom implementation)";
      });
    };
  };
  config = {
    programs.aerc = {
      enable = true;

      # incomplete support for all configuration options!
      extraAccounts =
        (lib.mapAttrs
          (name: accountConfig: with accountConfig; let
            quoteMailAddress = lib.replaceStrings [ "@" "\\" ] [ "%40" "%5C" ];
            # home-manager has no way to set if an account requires AUTH LOGIN
            # this emulats this by setting a list of known providers that do require it
            requiresLogin = lib.elem
              (lib.elemAt (lib.strings.splitString "@" address) 1)
              [ "mailbox.tu-dresden.de" ];
          in
          {
            source =
              if notmuch.enable
              then "notmuch://${config.accounts.email.maildirBasePath}"
              else "`imap://${quoteMailAddress userName}@${imap.host}`";
            source-cred-cmd = "`${lib.concatStringsSep " " passwordCommand}`";
            # TODO: remove when copy-to is implemented in aerc for notmuch
            outgoing =
              if notmuch.enable
              then "${./msmtp-wrapper} ${name}"
              else "`smtp${lib.optionalString requiresLogin "+login"}://${quoteMailAddress userName}@${smtp.host}`";
            outgoing-cred-cmd = "`${lib.concatStringsSep " " passwordCommand}`";
            from = "${realName} <${address}>";
            smtp-starttls = if smtp.tls.useStartTls then "yes" else "no";
            copy-to = "Sent";
            signature-file = toString (pkgs.writeText "signature-${name}" signature.text);
            pgp-key-id = gpg.key;
            pgp-auto-sign = gpg.signByDefault;
            pgp-opportunistic-encrypt = gpg.encryptByDefault;
          } // (lib.optionalAttrs notmuch.enable {
            query-map = toString (pkgs.writeText "aerc-query-map" ''
              Archive=not tag:inbox and not tag:sent
              Git=tag:git
              INBOX=tag:inbox
              Newsletter=tag:newsletter
              Sent=tag:sent
              Spam=tag:spam
              Trash=tag:deleted
              eBay Kleinanzeigen=tag:kleinanzeigen
              eBay=tag:ebay
            '');
            exclude-tags = lib.concatStringsSep "," [
              "archived"
              "deleted"
              "spam"
            ];
          }))
          (lib.filterAttrs
            (_: config: config.aerc-sbruder.enable)
            config.accounts.email.accounts));

      extraConfig = {
        general = {
          pgp-provider = "gpg"; # internal does not work

          # Allow world-readable accounts.conf (passwords are not stored in it, so it is ok)
          unsafe-accounts-conf = true;
        };

        ui = {
          index-format = "%-17.17D %-20.20n %Z %-20.20g %s";

          # See https://godoc.org/time#Time.Format
          timestamp-format = "2006-01-02 15:04 MST";
          this-day-time-format = "15:04";
          this-week-time-format = "Monday 15:04";
          this-year-time-format = "02 January";

          pinned-tab-marker = "車";

          border-char-vertical = "│";
          border-char-horizontal = "─";

          fuzzy-complete = true;

          #threading-enabled = true; # broken

          new-message-bell = false;
        };

        statusline = {
          display-mode = "icon";
        };

        viewer = {
          header-layout = lib.concatStringsSep "," [
            "From|To"
            "Cc|Bcc"
            "Subject"
            "Date"
            "Reply-To"
            "X-Mailer"
            "User-Agent"
          ];
        };

        compose = {
          editor = "nvim";

          header-layout = lib.concatStringsSep "," [
            "To|From"
            "Subject"
          ];

          address-book-cmd = "khard email --parsable --remove-first-line %s";
        };

        filters = {
          "subject,~^\\[PATCH" = "awk -f ${pkgs.aerc}/share/aerc/filters/hldiff";
          "text/plain" = "${./colorize}"; # taken from upstream and patched
          "text/html" = "html"; # internal filter
          "text/calendar" = "${pkgs.python3.withPackages (ps: with ps; [ vobject ])}/bin/python ${pkgs.aerc}/share/aerc/filters/show-ics-details.py"; # hacky fix for broken nix support
        };

        triggers = {
          new-email = "exec notify-send -i mail-unread-symbolic 'New e-mail from %n' '%s'";
        };

        templates = { };
      };

      extraBinds = {
        global = {
          # Binds are of the form <key sequence> = <command to run>
          # To use '=' in a key sequence, substitute it with "Eq": "<Ctrl+Eq>"
          # If you wish to bind #, you can wrap the key sequence in quotes: "#" = quit
          "<C-p>" = ":prev-tab<Enter>";
          "<C-n>" = ":next-tab<Enter>";
          "<C-t>" = ":term<Enter>";
        };

        messages = {
          "q" = ":quit<Enter>";

          "<C-r>" = ":exec notmuch new<Enter>";

          "j" = ":next<Enter>";
          "<Down>" = ":next<Enter>";
          "<C-d>" = ":next 50%<Enter>";
          "<C-f>" = ":next 100%<Enter>";
          "<PgDn>" = ":next 100%<Enter>";

          "k" = ":prev<Enter>";
          "<Up>" = ":prev<Enter>";
          "<C-u>" = ":prev 50%<Enter>";
          "<C-b>" = ":prev 100%<Enter>";
          "<PgUp>" = ":prev 100%<Enter>";
          "g" = ":select 0<Enter>";
          "G" = ":select -1<Enter>";

          "J" = ":next-folder<Enter>";
          "K" = ":prev-folder<Enter>";
          "H" = ":collapse-folder<Enter>";
          "L" = ":expand-folder<Enter>";

          "v" = ":mark -t<Enter>";
          "V" = ":mark -v<Enter>";

          "T" = ":toggle-threads<Enter>";

          "<Enter>" = ":view<Enter>";
          #"d" = ":prompt 'Really delete this message?' ':modify-labels +deleted'<Enter>"; # does not work
          "D" = ":modify-labels +deleted -inbox<Enter>";
          "A" = ":modify-labels -inbox<Enter>";

          "ms" = ":modify-labels +spam -inbox<Enter>";
          "mS" = ":modify-labels -spam +inbox<Enter>";
          "mn" = ":modify-labels +newsletter<Enter>";
          "mN" = ":modify-labels -newsletter<Enter>";

          "C" = ":compose<Enter>";

          "rr" = ":reply -a<Enter>";
          "rq" = ":reply -aq<Enter>";
          "Rr" = ":reply<Enter>";
          "Rq" = ":reply -q<Enter>";

          "c" = ":cf<space>";
          "$" = ":term<space>";
          "!" = ":term<space>";
          "|" = ":pipe<space>";

          "/" = ":search<space>";
          "\\" = ":filter<space>";
          "n" = ":next-result<Enter>";
          "N" = ":prev-result<Enter>";
          "<Esc>" = ":clear<Enter>";
        };

        view = {
          "/" = ":toggle-key-passthrough<Enter>/";
          "q" = ":close<Enter>";
          "O" = ":open<Enter>";
          "S" = ":save<space>";
          "|" = ":pipe<space>";
          "D" = ":modify-labels +deleted -inbox<Enter>";
          "A" = ":modify-labels -inbox<Enter>";

          "f" = ":forward<Enter>";
          "rr" = ":reply -a<Enter>";
          "rq" = ":reply -aq<Enter>";
          "Rr" = ":reply<Enter>";
          "Rq" = ":reply -q<Enter>";

          "H" = ":toggle-headers<Enter>";
          "<C-k>" = ":prev-part<Enter>";
          "<C-j>" = ":next-part<Enter>";
          "J" = ":next<Enter>";
          "K" = ":prev<Enter>";
        };

        "view::passthrough" = {
          "$noinherit" = "true";
          "$ex" = "<C-x>";
          "<Esc>" = ":toggle-key-passthrough<Enter>";
        };

        # Keybindings used when the embedded terminal is not selected in the compose view"
        compose = {
          "$ex" = "<C-x>";
          "<C-k>" = ":prev-field<Enter>";
          "<C-j>" = ":next-field<Enter>";
          "<tab>" = ":next-field<Enter>";
          "<backtab>" = ":prev-field<Enter>";
        };

        # Keybindings used when the embedded terminal is selected in the compose view
        "compose::editor" = {
          "$noinherit" = "true";
          "$ex" = "<C-x>";
          "<C-k>" = ":prev-field<Enter>";
          "<C-j>" = ":next-field<Enter>";
          "<C-p>" = ":prev-tab<Enter>";
          "<C-n>" = ":next-tab<Enter>";
        };

        # Keybindings used when reviewing a message to be sent
        "compose::review" = {
          "y" = ":send<Enter>";
          "n" = ":abort<Enter>";
          "p" = ":postpone<Enter>";
          "q" = ":choose -o d discard abort -o p postpone postpone<Enter>";
          "e" = ":edit<Enter>";
          "a" = ":attach<space>";
          "d" = ":detach<space>";
        };

        terminal = {
          "$noinherit" = "true";
          "$ex" = "<C-x>";

          "<C-p>" = ":prev-tab<Enter>";
          "<C-n>" = ":next-tab<Enter>";
        };
      };

      stylesets = {
        default = {
          "*.selected.reverse" = true;

          "title.reverse" = true;
          "header.bold" = true;

          "*error.bold" = true;
          "error.fg" = 1;
          "warning.fg" = 3;
          "success.fg" = 2;

          "statusline_default.bg" = 0;
          "statusline_error.fg" = 1;
          "statusline_error.reverse" = true;
          "statusline_success.fg" = 2;
          "statusline_success.reverse" = true;

          "msglist_unread.bold" = true;
          "msglist_deleted.fg" = 10;

          "tab.bg" = 11;
          "tab.selected.reverse" = false;
          "tab.selected.bg" = 12;
          "tab.fg" = 0;

          "completion_default.bg" = 0;
        };
      };
    };
  };
}