cyanrip/default.nix

@@ -0,0 +1,35 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, meson
+, ninja
+, pkg-config
+, ffmpeg
+, libcdio
+, libcdio-paranoia
+, curl
+, libmusicbrainz5
+}:
+
+stdenv.mkDerivation rec {
+  pname = "cyanrip";
+  version = "0.7.0";
+
+  src = fetchFromGitHub {
+    owner = "cyanreg";
+    repo = pname;
+    rev = "v${version}";
+    sha256 = "0lgb92sfpf4w3nj5vlj6j7931mj2q3cmcx1app9snf853jk9ahmw";
+  };
+
+  nativeBuildInputs = [ meson ninja pkg-config ];
+  buildInputs = [ ffmpeg libcdio libcdio-paranoia curl libmusicbrainz5 ];
+
+  meta = with lib; {
+    description = "Fully featured CD ripping program able to take out most of the tedium";
+    homepage = "https://github.com/cyanreg/cyanrip";
+    license = with licenses; [ lgpl21Plus lgpl3Plus ]; # some files have lgpl21Plus header, repo has lgpl3Plus LICENSE
+    maintainers = with maintainers; [ sbruder ];
+    platforms = platforms.unix;
+  };
+}

default.nix

@@ -19,6 +19,8 @@ in
 
   colorchord2 = callPackage ./colorchord2 { };
 
+  cyanrip = callPackage ./cyanrip { };
+
   deemix = callPythonPackage ./deemix { };
 
   fSpy = callPackage ./fSpy { };
@@ -37,6 +39,8 @@ in
 
   nsz = callPythonPackage ./nsz { };
 
+  oha = callPackage ./oha { };
+
   playgsf = callPackage ./playgsf { };
 
   snownews = callPackage ./snownews { };
@@ -48,4 +52,6 @@ in
   vgmstream = callPackage ./vgmstream { };
 
   VisiCut = callPackage ./VisiCut { };
+
+  x264-unstable = prev.x264.overrideAttrs (callPackage ./x264-unstable { });
 }

flake.nix

@@ -48,6 +48,7 @@
           inherit (pkgs)
             VisiCut
             colorchord2
+            cyanrip
             deemix
             fSpy
             face_morpher
@@ -55,11 +56,13 @@
             hcloud_exporter
             netstick
             nsz
+            oha
             playgsf
             snownews
             textidote
             unxwb
-            vgmstream;
+            vgmstream
+            x264-unstable;
 
           mpvScripts = lib.recurseIntoAttrs {
             inherit (pkgs.mpvScripts)

oha/default.nix

@@ -0,0 +1,28 @@
+{ lib, rustPlatform, fetchFromGitHub, openssl, pkg-config }:
+
+rustPlatform.buildRustPackage rec {
+  pname = "oha";
+  version = "0.4.5";
+
+  src = fetchFromGitHub {
+    owner = "hatoo";
+    repo = pname;
+    rev = "v${version}";
+    sha256 = "0grq9qk34i1k1nmw77d0f19qxq5f4hqax7x1pjrqmq972ix194wr";
+  };
+
+  cargoSha256 = "14cc4hzg755brmr657mbmiqwbf26sn252vn4cywp0zs6y63mmxfw";
+
+  nativeBuildInputs = [ pkg-config ];
+  buildInputs = [ openssl ];
+
+  doCheck = false; # tests require network
+
+  meta = with lib; {
+    description = "HTTP load generator, inspired by rakyll/hey with tui animation";
+    homepage = "https://github.com/hatoo/oha";
+    license = with licenses; [ mit ];
+    maintainers = with maintainers; [ sbruder ];
+    platforms = platforms.unix;
+  };
+}

x264-unstable/default.nix

@@ -0,0 +1,18 @@
+{ lib, fetchFromGitLab }:
+
+o: o // rec {
+  version = "unstable-2021-04-19";
+
+  src = fetchFromGitLab {
+    domain = "code.videolan.org";
+    owner = "videolan";
+    repo = o.pname;
+    rev = "b684ebe04a6f80f8207a57940a1fa00e25274f81";
+    sha256 = "06r6m1v88m532wbhk6al9imrsn1inwdjzrpmp97wrbdg6b2naygd";
+  };
+
+  meta = with lib; o.meta // {
+    description = "${o.meta.description} (unstable version)";
+    maintainers = with maintainers; [ sbruder ];
+  };
+}