let
  pkgs = import ./nixpkgs.nix {};

  # reproducible source
  gitignoreSrc = pkgs.fetchFromGitHub {
    owner = "hercules-ci";
    repo = "gitignore";
    rev = "c4662e662462e7bf3c2a968483478a665d00e717";
    sha256 = "sha256:1npnx0h6bd0d7ql93ka7azhj40zgjp815fw2r6smg8ch9p7mzdlx";
  };
  inherit (import gitignoreSrc { inherit (pkgs) lib; }) gitignoreSource;

  python = (pkgs.python38.withPackages (ps: with ps; [
    CommonMark
    jinja2
    pyyaml
  ]));

  texlive = pkgs.texlive.combine {
    inherit (pkgs.texlive) scheme-medium
      appendixnumberbeamer
      beamertheme-focus
      beamertheme-metropolis
      biber
      biblatex
      datetime
      datetime2
      datetime2-german
      enumitem
      fmtcount
      multirow
      pgfopts;
  };
in
pkgs.stdenv.mkDerivation {
  name = "presis";

  nativeBuildInputs = [
    python
    texlive
  ];

  src = gitignoreSource ./.;

  FONTCONFIG_FILE = pkgs.makeFontsConf {
    fontDirectories = with pkgs; [
      fira
      iosevka
    ];
  };

  enableParallelBuilding = true;

  dontFixup = true;

  installPhase = ''
    cp -r . $out;
  '';
}