seminararbeit/flake.nix

{
  description = "A very basic flake";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = { self, flake-utils, nixpkgs }: flake-utils.lib.eachDefaultSystem (system:
    let
      pkgs = nixpkgs.legacyPackages.${system};
    in
    rec {
      packages.seminararbeit =
        let
          texlive = pkgs.texlive.combine {
            inherit (pkgs.texlive) scheme-small
              beamertheme-metropolis
              biber
              biblatex
              csquotes
              datetime2
              datetime2-german
              enumitem
              geschichtsfrkl
              latexmk
              lipsum
              multirow
              pgfopts
              setspace
              todonotes
              tracklang;
          };
        in
        pkgs.stdenv.mkDerivation {
          name = "seminararbeit";

          nativeBuildInputs = [
            texlive
          ];

          src = self;

          FONTCONFIG_FILE = pkgs.makeFontsConf {
            fontDirectories = with pkgs; [ fira ];
          };

          enableParallelBuilding = true;

          # We only build a PDF
          dontFixup = true;

          installPhase = ''
            runHook preInstall

            mkdir $out

            cp seminararbeit.pdf presi/handout.pdf $out
            cp presi/index.pdf $out/presi.pdf

            runHook postInstall
          '';
        };

      defaultPackage = packages.seminararbeit;
    });
}