54 lines
1.4 KiB
Nix
54 lines
1.4 KiB
Nix
# SPDX-FileCopyrightText: 2021-2023 Simon Bruder <simon@sbruder.de>
|
|
#
|
|
# SPDX-License-Identifier: AGPL-3.0-or-later
|
|
|
|
final: prev:
|
|
let
|
|
inherit (prev) callPackage;
|
|
in
|
|
{
|
|
bwrap-helper = callPackage ./bwrap-helper { };
|
|
|
|
co2_exporter = callPackage ./co2_exporter { };
|
|
|
|
osu-lazer = callPackage ./osu-lazer { inherit (prev) osu-lazer; };
|
|
osu-lazer-sandbox = callPackage ./osu-lazer-sandbox { };
|
|
|
|
wordclock-dimmer = prev.python3Packages.callPackage ./wordclock-dimmer { };
|
|
|
|
sbruder = prev.recurseIntoAttrs {
|
|
contact = callPackage ./contact-page { };
|
|
imprint = callPackage ./imprint { };
|
|
};
|
|
|
|
libbluray = prev.libbluray.override {
|
|
withAACS = true;
|
|
withBDplus = true;
|
|
};
|
|
|
|
grml-zsh-config = prev.grml-zsh-config.overrideAttrs (o: o // {
|
|
postPatch = (o.postPatch or "") + ''
|
|
substituteInPlace etc/zsh/zshrc \
|
|
--replace 'isgrmlcd && HISTSIZE=500 || HISTSIZE=5000' "" \
|
|
--replace 'isgrmlcd && SAVEHIST=1000 || SAVEHIST=10000' ""
|
|
'';
|
|
});
|
|
|
|
# FIXME: Remove once khal from unstable passes tests again.
|
|
khal = prev.khal.overridePythonAttrs (o: { doCheck = false; });
|
|
|
|
mumble = prev.mumble.overrideAttrs (o: rec {
|
|
version = "1.5.517";
|
|
|
|
src = prev.fetchFromGitHub {
|
|
owner = "mumble-voip";
|
|
repo = "mumble";
|
|
rev = "v${version}";
|
|
sha256 = "sha256-NkpX1whtXDX3Q3UPnEO/Fq2LUX2MaJ/NI0oF7HudP+I=";
|
|
fetchSubmodules = true;
|
|
};
|
|
|
|
patches = [ ];
|
|
});
|
|
}
|